N E X T - GUNSHOP - Gratis lol

[Trixx]

MEMES.

 

Kontekst : : Folk jeg laver E2'med får tydeligt at vide at jeg ikke sælger mine E2'er, men giver dem(har sjældent taget penge for dem) til folk jeg spiller med, da jeg synes at folk selv skal lære det, og mener at det er 'scam' at sælge E2. Når man vælger at sælge min/en e2 som jeg har lavet store dele af uden tilladelse, ryger den på forum... JEG LAVER IKKE E2 FOR PROFIT

 

 

 

Spoiler

@name N E X T GUNSHOP WORKING
@inputs [Ctrl, EGP]:wirelink User:entity [R1, R2, R3, R4, R5, R6]:entity
@outputs 
@persist S:normal [Profit, HiredPercent, Sold, Earned, Used, Omsat, HiredPay] Price Dealer:entity ST
@persist [CurUser]:entity 
@persist Checked:table Shipments:array
@persist Welcome:string FWelcome:array 
@persist Wps:table Company:string IsBlacklisted 
@persist [Blacklist, BlacklistGangs, Hired]:table 
@trigger 

# OBS. Det meste af E2'en er lavet i marts 2018. Derfor var mine E2'skillz ret daarlige
##-min

CPU=cpuUsage()*1000000
CLKNAME = clkName()
FileName = fileName()

if(duped()|dupefinished()){reset()}
if(first())
{
    setName("N-E-X-T v 2.2")
    
    runOnChat(1)
    
    Profit = 4000
    HiredPercent = 50
    
    Wps = table(
    #[
        array(1,"AK47", 3000),
        array(2,"AK74", 2900),
        array(3,"Famas", 2900),
        array(4,"G3A3", 3200),

        array(7,"G36C", 3100),
        array(8,"M4A1", 3100),
        array(10,"M14", 4000),
        array(24,"SG552", 3000),
        array(25,"SG550", 3100),  

        array(20,"SKS", 4800),
        array(21,"RPK-47", 3800),
        
        array(23,"SR-25", 5500),
        array(12,"M24", 5600),
        array(13,"M21", 6000),
        array(11,"M82", 7000),
        
        array(9,"KS-23", 2400),
        array(22,"M3 Shotgun", 2600),
        
        array(14,"Raging Bull", 700),
        array(15,"M1911", 480),
        array(16,"OTs-33", 850),
        array(17,"P228", 600),
        array(5,"Deagle", 750),
        array(6,"Glock-20", 550),
        
        array(27,"Grenade", 5000)
        ]# # GAMLE VAABEN. TILFOEJ DEM SELV HVIS I VIL KUNNE BESTILLE IGENNEM HER 1 = ID, 2=NAVN, 3=Pris
    )

    
    function table string:getMatch(){
        local Table = table()
        
        for(K=1,Wps:count())
        {
            local Arr = Wps[K,array]
            
            if (opcounter()>3000){break}
            
            local Str = Arr[2,string]
            
            if(Str:lower():matchFirst(This:lower()))
            {
                Table[Table:count()+1,array] = Wps[K,array]
            }
        }
    
        return Table
    }
    
    function string number:mf() {
        local Formatted = This+""
        local Last = ""
    
        while (1) {
            Formatted = Formatted:replaceRE("^(-?%d+)(%d%d%d)", "%1.%2")
            if(Formatted==Last){break}
            Last=Formatted
        }
        return Formatted
    }    

    function string message(S:string){printColor(vec(255),"[ ",vec(34,96,180),"N-E-X-T",vec(255)," ] ",S)}
    
    function entity tx_FindPly(Str:string){
        
        return Str:sub(0,7) == "STEAM_0" ? findPlayerBySteamID(Str) : findPlayerByName(Str)
    } 

    function number canDilv()
    {
        Dest = getDestinationIDs()
        
        return Dest:count()>0  
    }
    
    function number orderWeapon(Weapon:string, Amount)
    {
        if(Weapon=="") {message("No Weapon") return 0}   
        if(Amount < 1 | Amount > 50){message("Wrong amount (1-50)") return 0}
        if(!canDilv()){message("Kan ikke finde et sted at levere pakken til!") return 0}   
        local Find = Weapon:getMatch()
        if(Find:count()>1){message("Fandt flere v"+aa()+"ben med navnet: "+Weapon) return 0}
        local OO = orderProduct("SWC", Find[1,array][1,number], Amount, Company, entity(Dest[1,number])) 
        if(OO)
        {
            message("Bestiller "+Amount+"x "+Find[1,array][2,string])
            Used += (Find[1,array][3,number] * Amount)
            return 1
        }
    }

    function void getCompany() {
        
        hint("Finder et nyt fragtfirma", 2000)
        
        local CompanyPrice = 10000
        local Id = 0
        
        foreach(K, C:string = getDeliveryCompanyIDs()) {
            Id++
            
            local CO = getDeliveryCompany(C)
            
            local PD = CO["Prices",table]["FromWeb",number] + CO["Prices",table]["ToHouse",number]
            local PS = CO["Prices",table]["FromPerson",number] + CO["Prices",table]["ToHouse",number]
            
            if((PD + PS) < CompanyPrice) {
                CompanyPrice = PD + PS
                Company = C
            }
        }
           
        if(Id == 0) {
            CompanyPrice = 3500
        }
    } 
    
    function number entity:tBlacklist()
    {
        if(!This:isPlayer()){return 0}
        Blacklist[This:steamID(), number] = 1   
        message("Blacklisted: "+This:name())
    }
    
    function number entity:tWhitelist()
    {
        if(!This:isPlayer()){return 0}
        Blacklist:remove(This:steamID())
        
        message("Removed blacklist for: "+This:name())
    }
    
    function number entity:isBlacklisted()
    {
        if(!This:isPlayer()){return 0}
        
        return Blacklist[This:steamID(), number]
    }
    
    function number entity:tBlacklistGang()
    {
        if(!This:isPlayer()){return 0}
        
        local Gang = This:getGangID()
        local GangName = This:getGang()
        
        BlacklistGangs[Gang, number] = 1  
        message("Blacklisted gang: "+GangName) 
    }
    
    function number entity:tWhitelistGang()
    {
        if(!This:isPlayer()){return 0}
        
        local Gang = This:getGangID()
        local GangName = This:getGang()
        
        BlacklistGangs:remove(Gang)
        
        message("Removed blacklist for gang: "+GangName)
    }
    
    function number entity:isGangBlacklisted()
    {
        if(!This:isPlayer()){return 0}
        
        return BlacklistGangs[This:getGangID(), number]
    }
    
    function number entity:hire()
    {
        if(!This:isPlayer()){return 0}
        
        Hired[This:steamID(), entity] = This
        
        message("Ansatte: "+This:name())
        
        return 1
    }

    function number entity:isHired()
    {
        return Hired[This:steamID(), entity]:isValid()
    }
    
    function number entity:fire()
    {
        #if(!This:isPlayer()){return 0}
        if(!This:isHired()) {message("Nigro is not ansat") return 0}
        Hired:remove(This:steamID())
        
        message("Fyret: "+This:name())
        
        return 1
    }

    
    function void payHired()
    {
        if(Hired:count()<1){return}
        
        message("Fors"+oe()+"get at betale ansatte!")
        local PP = ((HiredPay / 100) * HiredPercent) / (Hired:count()+1)
        foreach(K, E:entity = Hired)
        {
            moneyGive(E, PP)
            hint("Betaler - "+E:name(), 1500)
        }   
        HiredPay = 0
    }
    
    
    function number wirelink:egpButton(Idx:number,Ply:entity){ # Spilder en del ops
        TL = This:egpPos(Idx) - This:egpSize(Idx) / 2 * (0 ? 0 : 1)
        BR = This:egpPos(Idx) + This:egpSize(Idx) / (0 ? 1 : 2)
        Cur = This:egpCursor(Ply) return inrange(Cur, TL, BR) exit()
    }
    
    function number entity:shipPrice()
    {
        return This:isShipment() ? This:shipmentPrice() + Profit + (IsBlacklisted*20000) : 0
    }
    
    function string entity:shipName()
    {
        return This:isShipment() ? This:shipmentName() : "Udsolgt"
    }
    
    function number getTotalWeapons()
    {
        local Nr = 0
        
        Nr+=R1:shipmentAmount()  
        Nr+=R2:shipmentAmount()  
        Nr+=R3:shipmentAmount()  
        Nr+=R4:shipmentAmount()  
        Nr+=R5:shipmentAmount()  
        Nr+=R6:shipmentAmount()   
        
        return Nr
    }

    function void wirelink:drawLogin()
    {
        S=1
        This:egpClear()
        This:egpBox(1, vec2(256,256), vec2(516,516)) This:egpColor(1, vec4(51,51,51,180))
        This:egpBox(2, vec2(256,56), vec2(300,30)) This:egpColor(2, vec4(28, 172, 120,150))
        
        This:egpBox(3,vec2(390,160), vec2(150,30)) This:egpColor(3, vec4(255, 174, 66,95))
        This:egpAngle(3,90)
        This:egpBox(5,vec2(122,160), vec2(150,30)) This:egpColor(5, vec4(255, 174, 66,95))
        This:egpAngle(5,90)        
        
        This:egpBox(4, vec2(256,266), vec2(300,30)) This:egpColor(4, vec4(28, 172, 120,150))
        
        This:egpText(6,"N E X T", vec2(256,150)) This:egpAlign(6,1,1) This:egpFont(6,"Courier New",50)
        This:egpText(7,"G U N S H O P", vec2(256,180)) This:egpAlign(7,1,1) This:egpFont(7,"Courier New",30)       
        
        This:egpBox(8, vec2(256,370), vec2(300,60)) This:egpColor(8, vec4(36,36,36,156))
        This:egpBox(9, vec2(170,370), vec2(1,50))
        This:egpBox(11, vec2(256,405), vec2(300,2))
        #[mini logo]#
        This:egpTriangle(13, vec2(116,386), vec2(116,346), vec2(156,346)) This:egpColor(13, vec4(255, 174, 66,95))
        This:egpTriangle(14, vec2(116,394), vec2(156,394), vec2(156,354)) This:egpColor(14, vec4(255, 174, 66,95))
        This:egpColor(14, vec4(28, 172, 120,150))
        
        This:egpBox(10, vec2(256,256), vec2(512,512))
        This:egpMaterial(10, "gui/gradient_up")
        This:egpColor(10, vec4(0, 0, 0,150))
        
        
        #[Login Box]#
        This:egpBox(15, vec2(256,440), vec2(300,40)) This:egpColor(15, vec4(255, 174, 66,95))
        This:egpText(16,"LOGIN",vec2(256,440)) This:egpColor(16, vec4(51,51,51,250)) This:egpAlign(16,1,1) This:egpFont(16,"Courier New",30)
        

        This:egpText(17,"- N E X T -", vec2(256,310)) This:egpAlign(17,1,1) This:egpFont(17,"Courier New",15)
        This:egpText(18,"- CREDITS -", vec2(256,325)) This:egpAlign(18,1,1) This:egpFont(18,"Courier New",12)
        
        
        This:egpBox(19, vec2(456,260), vec2(10,440)) This:egpColor(19, vec4(255, 174, 66,95))
        This:egpBox(20, vec2(56,260), vec2(10,440)) This:egpColor(20, vec4(255, 174, 66,95))
    }
    
    function void addWeapon(Nr)
    {
        local Ent = Shipments[Nr,entity]
        if(!Ent:isShipment()){return}
        
        if(Checked[Nr,number]){
            Price-=Ent:shipPrice()
        }else
        {
            Price+=Ent:shipPrice()
        }
        
        Checked[Nr, number] = !Checked[Nr, number]
        
        local Col = Checked[Nr, number] ? vec(255, 174, 66) : vec(255,255,255)
        
        EGP:egpColor(110+Nr, Col)
        
        EGP:egpSetText(49, Price+",-")
        
    }
    
    function array getShipments()
    {
        local Arr = array()
        if(R1:isShipment()){Arr:pushEntity(R1)}   
        if(R2:isShipment()){Arr:pushEntity(R2)} 
        if(R3:isShipment()){Arr:pushEntity(R3)} 
        if(R4:isShipment()){Arr:pushEntity(R4)} 
        if(R5:isShipment()){Arr:pushEntity(R5)} 
        if(R6:isShipment()){Arr:pushEntity(R6)} 
        
        return Arr
    }
    
    function void wirelink:drawBuyWeps()
    {
        S=2
        This:egpClear()
        This:egpBox(1, vec2(256,256), vec2(516,516)) This:egpColor(1, vec4(51,51,51,180))
        This:egpBox(2, vec2(256,256), vec2(512,512))
        This:egpMaterial(2, "gui/gradient_up")
        This:egpColor(2, vec4(0, 0, 0,150))
        
        Checked:clear()
        Price = 0
        
        IsBlacklisted = 0
        
        if(CurUser:isBlacklisted() || CurUser:isGangBlacklisted())
        {
            IsBlacklisted = 1   
        }
        
        Shipments = getShipments()
        
        for(I=1,6)
        {
            local YN = I>3 ? 1 : 0
            local X = 110 + (146*(I-(YN ? 4 : 1)))
            
            local Y = YN ? 112 : 0
            
            This:egpBox(100+I, vec2(X,256+Y), vec2(100,100)) 
            This:egpColor(100+I, vec4(28,172,120,90)) 
            
            This:egpBoxOutline(110+I, vec2(X,256+Y), vec2(104,104)) 
            
            This:egpText(120+I, "Udsolgt", vec2(X,246+Y))
            This:egpAlign(120+I, 1,1)
            This:egpFont(120+I, "Courier New",20)
            
            This:egpText(130+I, "0,-", vec2(X,266+Y))
            This:egpAlign(130+I, 1,1)
            This:egpFont(130+I, "Courier New",20)
        }   

        local Y=130
        local X=25
        This:egpTriangle(15, vec2(156+X,310-Y), vec2(306+X,310-Y), vec2(306+X,160-Y))
        This:egpColor(15, vec4(28, 172, 120,150))
        This:egpTriangle(16, vec2(156+X,302-Y), vec2(156+X,152-Y), vec2(306+X,152-Y))
        This:egpColor(16, vec4(255, 174, 66,95))
        
        
        This:egpText(17,"N E X T" ,vec2(96,100)) This:egpAlign(17,1,1) This:egpFont(17,"Courier New",20) 
        This:egpText(18,"G U N S H O P",vec2(96,120)) This:egpAlign(18,1,1) This:egpFont(18,"Courier New",16) 
        This:egpBox(22, vec2(100,135), vec2(140,5)) This:egpColor(22, vec4(255,174,66,95))
        
        This:egpText(19,"T I L B A G E", vec2(420,100)) This:egpAlign(19,1,1) This:egpFont(19,"Courier New",20)
        This:egpText(20,"T I L  S T A R T", vec2(420,120)) This:egpAlign(20,1,1) This:egpFont(20,"Courier New",16)
        This:egpBox(21, vec2(420,135), vec2(140,5)) This:egpColor(21, vec4(255,174,66,95))
        
        
        This:egpBox(46, vec2(256,470), vec2(300,50)) This:egpColor(46, vec4(255, 174, 66,95))
        This:egpBox(47, vec2(256,500), vec2(300,5))  This:egpColor(47, vec4(28, 172, 120,150))
        
        
        This:egpText(48,"B E T A L",vec2(256,460)) This:egpAlign(48,1,1) This:egpFont(48,"Courier New",30) This:egpColor(48, vec4(51,51,51,250))
        This:egpText(49,"0,-",vec2(256,480)) This:egpAlign(49,1,1) This:egpFont(49,"Courier New",30) This:egpColor(49, vec4(51,51,51,250))
        
        This:egpBox(50, vec2(256, 80), vec2(512, 216))
        
        This:egpAlpha(50, 0)
        
        timer("updateShipments", 275)
        timer("distancecheck", 2500)

    }
    
    
    function void wirelink:drawSetting(N, Str:string)
    {
        Pos = 139 + N*34
        This:egpBox(130+N, vec2(354,Pos), vec2(136,30)) This:egpColor(130+N, vec(51,51,51))
        
        This:egpText(120+N,Str, vec2(354,Pos)) 
        This:egpFont(120+N,"Courier New",17) 
        This:egpAlign(120+N,1,1)     
    }
    
    function void wirelink:drawSetting(N, Str:string, Str2:string)
    {
        Pos = 139 + N*34
        This:egpBox(130+N, vec2(354,Pos), vec2(136,30)CONTEXT : : Folk jeg laver E2'med får tydeligt at vide at jeg ikke sælger mine E2'er, men giver dem(har sjældent taget penge for dem) til folk jeg spiller med, da jeg synes at folk selv skal lære det, og mener at det er 'scam' at sælge E2. Når man vælger at sælge min/en e2 som jeg har lavet store dele af uden tilladelse, ryger den på forum... JEG LAVER IKKE E2 FOR PROFIT) This:egpColor(130+N, vec(51,51,51))
        
        This:egpText(120+N,Str, vec2(354,Pos+7)) 
        This:egpFont(120+N,"Courier New",17) 
        This:egpAlign(120+N,1,1)   
        
        This:egpText(140+N,Str2, vec2(354,Pos-6)) 
        This:egpFont(140+N,"Courier New",17) 
        This:egpAlign(140+N,1,1)  
        
    }

    function wirelink:drawCtrl()
    {
        This:egpClear()
        This:egpBox(1, vec2(256,256), vec2(516,516)) This:egpColor(1, vec4(51,51,51,180))
        This:egpBox(2, vec2(256,256), vec2(512,512))
        This:egpMaterial(2, "gui/gradient_up")
        This:egpColor(2, vec4(0, 0, 0,150))
                
                
        This:egpBox(3, vec2(256,256), vec2(356,356)) This:egpColor(3, vec4(51,51,51,180))
        This:egpBoxOutline(4, vec2(256,256), vec2(365,360)) This:egpColor(4, vec4(255, 174, 66,95))
        This:egpText(5, "K O N T R O L - P A N E L", vec2(256,256)) This:egpAlign(5,1,1) This:egpFont(5,"Courier New",26)
        This:egpAngle(5,270)
                
                
        This:egpBox(6, vec2(156,256), vec2(156,350)) This:egpColor(6, vec4(255,174,66,95))
        
        This:egpText(20,"Information", vec2(156,100)) This:egpFont(20,"Courier New",22) This:egpAlign(20,1,1)
        
        This:egpBox(17, vec2(158,116), vec2(140,1))
        
        
        This:egpText(7,"Antal Vagter", vec2(156,130)) This:egpFont(7,"Courier New",17) This:egpAlign(7,1,1)
        This:egpText(8,"0", vec2(156,145)) This:egpFont(8,"Courier New",17) This:egpAlign(8,1,1)
        
        This:egpText(9,"Penge Tjent", vec2(156,170)) This:egpFont(9,"Courier New",17) This:egpAlign(9,1,1)
        This:egpText(10,"0", vec2(156,185)) This:egpFont(10,"Courier New",17) This:egpAlign(10,1,1)
               
        This:egpText(11,"Penge Brugt", vec2(156,210)) This:egpAlign(11,1,1) This:egpFont(11,"Courier New",17)
        This:egpText(12,"0", vec2(156,230)) This:egpAlign(12,1,1) This:egpFont(12,"Courier New",17)
                
        This:egpText(13,"Penge Omsat", vec2(156,260)) This:egpAlign(13,1,1) This:egpFont(13,"Courier New",17)
        This:egpText(14,"0", vec2(156,280)) This:egpAlign(14,1,1) This:egpFont(14,"Courier New",17)
               
        This:egpText(15,"Antal af v"+aa()+"ben", vec2(156,310)) This:egpAlign(15,1,1) This:egpFont(15,"Courier New",17)
        This:egpText(16,"0", vec2(156,330)) This:egpAlign(16,1,1) This:egpFont(16,"Courier New",17)
            
            

        This:egpBox(18, vec2(156,396), vec2(120,30)) This:egpColor(18, vec(51,51,51))
        This:egpText(19,"G E M", vec2(156,396)) This:egpFont(19,"Courier New",17) This:egpAlign(19,1,1)   
                
                
        This:egpBox(25, vec2(354,256), vec2(156,350)) This:egpColor(25, vec4(255,174,66,95))
        
        This:egpText(26,"Funktion", vec2(354,100)) This:egpFont(26,"Courier New",22) This:egpAlign(26,1,1)
        
        This:egpBox(27, vec2(354,116), vec2(140,1))        
        

        timer("drawSettings", 500)
    }
    
    function void wirelink:drawSettings()
    {
        This:drawSetting(0, Profit:mf(), "Profit")
        
        This:drawSetting(1, "Ingen", "Dealer")
        
        This:drawSetting(2, "Spiller", "Blacklist")
        
        This:drawSetting(3, "Spiller", "Whitelist")
        
        This:drawSetting(4, "Bande", "Blacklist")
        
        This:drawSetting(5, "Bande", "Whitelist")
        
        if(Wps:count()>0) {
            This:drawSetting(6, "Bestil v"+aa()+"ben" )
        } 
    }    
    timer("start", 500)
}

elseif((~User & User) & (ops()<200 & opcounter()<1000))
{
    if(S==1)
    {
        if(EGP:egpButton(15, User))
        {
            S=5
            EGP:egpText(75, "-", vec2(176,375))
            EGP:egpAlign(75, 0,1)
            EGP:egpFont(75, "Courier New",30)
            timer("Name",100)
            CurUser=User
            local Name = CurUser:name()
            local N = Name:length()>11 ? Name:sub(0,12)+".." : Name
            FWelcome=N:explode("")
            Welcome=" "
        }
    }elseif(S==2)
    {
        if(CurUser==User)
        {
            if(EGP:egpButton(101, User)){addWeapon(1)}
            elseif(EGP:egpButton(102, User)){addWeapon(2)}
            elseif(EGP:egpButton(103, User)){addWeapon(3)}  
            elseif(EGP:egpButton(104, User)){addWeapon(4)}  
            elseif(EGP:egpButton(105, User)){addWeapon(5)}  
            elseif(EGP:egpButton(106, User)){addWeapon(6)}    
            
            elseif(EGP:egpButton(46, User))
            {
                moneyRequest(User, Price, "Pornoblad")   
            }elseif(EGP:egpButton(50, User))
            {
                EGP:drawLogin()
            }
        }   
    }
}

elseif(clk(CLKNAME)){
    if(opcounter()<3500 & CPU<110){
        switch(CLKNAME)
        {
            case "updateShipments",
            
                if(S==2)
                {
                    foreach(K, Ent:entity = Shipments)
                    {
                        EGP:egpSetText(120+K, Ent:shipName():sub(0,9))   
                        EGP:egpSetText(130+K, Ent:shipPrice():toString()+",-")  
                    }
                }
                
            break,
            
            case "distancecheck",
                if(S==2){
                    if(CurUser:pos():distance(EGP:entity():pos())>100)
                    {
                        EGP:drawLogin()
                    }
                    timer("distancecheck",5000)
                }
            break,
            
            case "Name",
                if(S==5){
                        if(Welcome:length()<=FWelcome:count()){
                        Welcome=Welcome+FWelcome[Welcome:length(),string]
                        EGP:egpSetText(75,Welcome:sub(2))
                        timer("Name",100)
                    }
                    else{EGP:drawBuyWeps()} 
                }
            break,
            
            case "drawSettings",
            
                Ctrl:drawSettings()
            
            break,
            
            case "drawCtrl",
                Ctrl:drawCtrl()
            break,
            
            case "start",
                EGP:drawLogin()
    
                timer("drawCtrl", 2500)
                timer("updatectrl", 60000)
                timer("payhired", 300000)
                timer("update-company", 5000)
            break,
            
            case "payhired",
            
                payHired()
                timer("payhired", 300000)
                
            break
            
            case "updatectrl",
                Ctrl:egpSetText(120, Profit:mf())
                Ctrl:egpSetText(8, Hired:count():toString())
                Ctrl:egpSetText(10, Earned:mf())
                Ctrl:egpSetText(12, Used:mf())
                Ctrl:egpSetText(14, Omsat:mf())
                
                Ctrl:egpSetText(16, getTotalWeapons():toString())
            
                local St = (Dealer != owner() & Dealer)
                local Name = St ? Dealer:name() : "Ingen" 
            
                Ctrl:egpSetText(121, Name)
                
                stoptimer("updatectrl")
                timer("updatectrl", 60000)
                
            break,
            
            case "update-company",
            
                getCompany()
                
                timer("update-company", 300000)
            
            break,
        }
    }else
    {
       # hint("Bad Performance", 2500)
        timer(CLKNAME,2500)
    }
}

elseif(moneyClk("Pornoblad"))
{
    local Am = 0
    foreach(K, Ent:entity = Shipments)
    {
        if(Checked[K, number]==1)
        {
               
            Sold++
            Earned += Profit
            Omsat+=Ent:shipPrice()
            
            HiredPay+=Profit
            
            Am+=Ent:shipmentPrice()
            
            local Js = Ent:ejectWeapon()
            if(!Js)
            {
                print("Fejl i at ejecte et v"+aa()+"ben!")
            }
        }
    }
    
    moneyGive(Dealer, Am)
    
    
    EGP:drawLogin()
    CurUser = noentity()
}elseif(moneyNoClk("Pornoblad") || moneyTimeout("Pornoblad"))
{
    EGP:drawLogin()
    CurUser = noentity()
}

if(chatClk(owner())){
    
    local LS = lastSaid():lower()
    local LP = lastSpoke()
    local LSS = LS:explode(" ")
    
    local OE = owner():aimEntity()
    
    if(OE == Ctrl:entity() & ->Ctrl)
    {
        
        local Ply = tx_FindPly(LS)
        
        if(Ctrl:egpButton(130, LP))
        {
            Profit = LS:toNumber()
            Ctrl:egpSetText(120, Profit:mf()) 
        }
        elseif(Ctrl:egpButton(132, LP))
        {
            Ply:tBlacklist()
        }elseif(Ctrl:egpButton(133, LP))
        {
            Ply:tWhitelist()
        }elseif(Ctrl:egpButton(134, LP))
        {
            Ply:tBlacklistGang()
        }elseif(Ctrl:egpButton(135, LP))
        {
            Ply:tWhitelistGang()
        }elseif(Ctrl:egpButton(136, LP))
        {
            orderWeapon(LSS[1, string], LSS[2,string]:toNumber())
            timer("updatectrl", 50)
        }
        elseif(Ctrl:egpButton(131, LP))
        {
            local St = 0
            if(Ply == owner() || !Ply)
            {
                Dealer = noentity()
                St = 0
            }else
            {
                Dealer = Ply
                St = 1
            }
            
            local Name = St ? Dealer:name() : "Ingen" 
            
            Ctrl:egpSetText(121, Name)
            
        }
        
        hideChat(1)
    }
}

if(chatClk(owner()))
{
    if(owner():aimEntity() != Ctrl:entity())
    {
        LS = owner():lastSaid():lower():explode(" ")
        if(LS[1,string]!="!shop"){exit()}
        local Cmd = LS[2,string]
        local Target = findPlayerByName(LS[3,string])
        if(LS[3,string]==""){Target = noentity()}
        hideChat(1)
        switch(Cmd)
        {
            case "profit",
                Arg = LS[3,string]:toNumber()
                if(Arg !=0)
                {
                    Profit = Arg
                    message("Profit sat til: "+Profit)   
                }else{message("Profit: "+Profit)}
                
                Ctrl:egpSetText(120, Profit:toString())
                
            break,
            case "remain",
                if(R1:isShipment()){printColor(vec(255),R1:shipmentName()+" - "+R1:shipmentAmount())}
                if(R2:isShipment()){printColor(vec(255),R2:shipmentName()+" - "+R2:shipmentAmount())}
                if(R3:isShipment()){printColor(vec(255),R3:shipmentName()+" - "+R3:shipmentAmount())}
                if(R4:isShipment()){printColor(vec(255),R4:shipmentName()+" - "+R4:shipmentAmount())}
                if(R5:isShipment()){printColor(vec(255),R5:shipmentName()+" - "+R5:shipmentAmount())}
                if(R6:isShipment()){printColor(vec(255),R6:shipmentName()+" - "+R6:shipmentAmount())}   
            
            break,
            case "logout",
                EGP:drawLogin()
                message("Loggede Cancer Barn UD!")
            break,
            
            case "sold",
                message("Du har solgt "+Sold+" v"+aa()+"ben, og har tjent "+Earned+" kr")
            break,
            
            case "bestil",
                local Wpn = LS[3,string]
                local Am = LS[4,string]:toNumber()
                
                if(Wpn=="") {message("brug !shop bestil <V"+aa()+"ben> <Antal>") break}   
                if(Am<1 | Am>50){message("brug !shop bestil <V"+aa()+"ben> <Antal>") break}
                        
                orderWeapon(Wpn, Am)
        
            break
            
            case "blacklist", 
                
                if(!Target:isPlayer()) { message("Brug !shop blacklist <Spiller>") break }
                
                if(Target:isBlacklisted()) {message(Target:name()+ " er allerade blacklisted.") break}
                
                Target:tBlacklist()
            
            break,
            
            case "unblacklist",
            
                if(!Target:isPlayer()) { message("Brug !shop unblacklist <Spiller>") break }
                
                if(!Target:isBlacklisted()) {message(Target:name()+ " er ikke blacklisted.") break}
                
                Target:tWhitelist()
                
            break,
            
            case "blacklistgang",
                   
                if(!Target:isPlayer()) { message("Brug !shop blacklistgang <Spiller's Gang>") break }
                
                if(Target:getGangID()==0){ message(Target:name()+" er ikke med i noget gang!") break}
                
                if(Target:isGangBlacklisted()) {message(Target:getGang()+ " er allerade blacklisted.") break}
                
                Target:tBlacklistGang()
                
            break,
            
            case "unblacklistgang",
                   
                if(!Target:isPlayer()) { message("Brug !shop unblacklistgang <Spiller's Gang>") break }
                
                if(Target:getGangID()==0){ message(Target:name()+" er ikke med i noget gang!") break}
                
                if(!Target:isGangBlacklisted()) {message(Target:getGang()+ " er ikke blacklisted.") break}
                
                
                
                Target:tWhitelistGang()
                
            break,
            
            case "ans"+ae()+"t",
            
                if(!Target:isPlayer()) { message("Brug !shop ans"+ae()+"t <Spiller>") break }
                
                if(Target:isHired()) {message(Target:name()+" er allerade ansat!") break}
                
                Target:hire()
                
                
            break,
            
            case "fyr",
            
                if(!Target:isPlayer()) { message("Brug !shop fyr <Spiller>") break }
                
                if(!Target:isHired()) {message(Target:name()+" er ikke ansat!") break}
                
                Target:fire()
            break,
            
            default,
                message("
profit
remain <Hvor mange vaaben du har tilbage>
logout
sold <Hvor mange penge du har tjent, og hvor mange vaaben du har solgt>
bestil
blacklist
unblacklist
blacklistgang <Brug navnet paa en der er med i ganget der skal blacklistes>
unblacklistgang
ans"+ae()+"t <Deler profitten med alle ansatte>
fyr")
            break,
        } 
    }
}

if(~EGP &EGP){reset()}
if(~Ctrl &Ctrl){Ctrl:drawCtrl()}

E2'en er på ingen måde perfekt, da den er lidt gammel. Men folk bør kunne lære lidt af den

 

 

 

 

 

 

[Sunix]

Skulle lige til at købe den.. SIKE lol

[OSSI]

Er den ik ny? Lol

[West]

11 timer siden, OSSI skrev:

Er den ik ny? Lol

 

Nej, det var en E2 som kun en lille vennegruppe havde. Så blev der lidt kaos også røg E2en ud på markedet, ligesom SkyBank.

[Trixx]

5 timer siden, Bims skrev:

 

Nej, det var en E2 som kun en lille vennegruppe havde. Så blev der lidt kaos også røg E2en ud på markedet, ligesom SkyBank.

Og Kaos = At der var et par stykker der mente at fordi at jeg ikke var så aktiv mere, synes de at det var okay at lave profit på mine E2'er uden at jeg måtte få det af vide(fik det af vide af kagen) / få et cut...